etDeviceInfo Sample Program Source Code

Private Sub FillVoiceDevices()
    etLine1.DeviceActive = True
    If (Not etLine1.DeviceActive) Then
    Text1.Text = Text1.Text & vbTab & "Error opening device = " & _
                 etLine1.ErrorText & vbCrLf
        If etLine1.ErrorNumber = INVALID_SERIAL_NUMBER Then
            MsgBox ("Error opening line device: " & etLine1.ErrorText & vbCrLf & _
                    vbCrLf & "See the help topic:" & vbCrLf & vbCrLf & _
                    vbTab & "Why Serial Numbers Are Important")
        End If
    Else
        If (Not etLine1.PhoneAvailable) Then
            Text1.Text = Text1.Text & vbTab & "TAPI Phone Device = <Not " & _
                         "Available>" & vbCrLf
        Else
            etPhone1.DeviceID = etLine1.PhoneID
            Text1.Text = Text1.Text & vbTab & "TAPI Phone Device ID = " & _
                         Str(etPhone1.DeviceID) & vbCrLf
            Text1.Text = Text1.Text & vbTab & "TAPI Phone Device Name = " & _
                         etPhone1.DeviceName & vbCrLf
        End If

        If (Not etLine1.WavePlayAvailable) Then
            Text1.Text = Text1.Text & vbTab & "Wave Play Device = <Not " & _
                         "Available>" & vbCrLf
        Else
            etPlay1.DeviceID = etLine1.WavePlayID
            Text1.Text = Text1.Text & vbTab & "Wave Play Device ID = " & _
                         Str(etPlay1.DeviceID) & vbCrLf
            Text1.Text = Text1.Text & vbTab & "Wave Play Device Name = " & _
                         etPlay1.DeviceName & vbCrLf
        End If

        If (Not etLine1.WaveRecordAvailable) Then
            Text1.Text = Text1.Text & vbTab & "Wave Record Device = <Not " & _
                         "Available>" & vbCrLf
        Else
            etRecord1.DeviceID = etLine1.WaveRecordID
            Text1.Text = Text1.Text & vbTab & "Wave Record Device ID = " & _
                         Str(etRecord1.DeviceID) & vbCrLf
            Text1.Text = Text1.Text & vbTab & "Wave Record Device Name = " & _
                         etRecord1.DeviceName & vbCrLf
        End If
        etLine1.DeviceActive = False
    End If
End Sub


Private Sub FillText()
Dim X As Integer

  Text1.Text = ""
  For X = 0 To etLine1.DeviceCount - 1
    etLine1.DeviceID = X
    If (OptionData.Value) Then
      If ((((etLine1.DeviceCapabilitiesBearerModes And LINEBEARERMODE_DATA)_
            <> 0) Or _
          ((etLine1.DeviceCapabilitiesBearerModes And LINEBEARERMODE_PASSTHROUGH)_
            <> 0)) And _
         ((etLine1.DeviceMediaModesAvailable And LINEMEDIAMODE_DATAMODEM) <> 0))_
        Then
          Text1.Text = Text1.Text & etLine1.DeviceName & vbCrLf
      End If
    Else
      If (OptionFax.Value) Then
        If ((((etLine1.DeviceCapabilitiesBearerModes And LINEBEARERMODE_DATA)_
             <> 0) Or _
           ((etLine1.DeviceCapabilitiesBearerModes And _
             LINEBEARERMODE_PASSTHROUGH) <> 0)) And _
           (((etLine1.DeviceMediaModesAvailable And LINEMEDIAMODE_G3FAX) <> 0) Or_
           ((etLine1.DeviceMediaModesAvailable And LINEMEDIAMODE_G4FAX) <> 0)))_
          Then
          Text1.Text = Text1.Text & etLine1.DeviceName & vbCrLf
          If ((etLine1.DeviceMediaModesAvailable And LINEMEDIAMODE_G3FAX)<>0) Then
            Text1.Text = Text1.Text & vbTab & "Group 3 Fax" & vbCrLf
          End If
          If ((etLine1.DeviceMediaModesAvailable And LINEMEDIAMODE_G4FAX)<>0) Then
            Text1.Text = Text1.Text & vbTab & "Group 4 Fax" & vbCrLf
          End If
        End If
      Else
        If (OptionVoice.Value) Then
          If (((etLine1.DeviceCapabilitiesBearerModes And LINEBEARERMODE_VOICE)_
              <> 0) And _
             (((etLine1.DeviceMediaModesAvailable And_
                LINEMEDIAMODE_INTERACTIVEVOICE) <> 0) Or _
             ((etLine1.DeviceMediaModesAvailable And_
               LINEMEDIAMODE_AUTOMATEDVOICE) <> 0))) Then
            Text1.Text = Text1.Text & etLine1.DeviceName & vbCrLf
            FillVoiceDevices
          End If
        End If
      End If
    End If
  Next X
  If (Text1.Text = "") Then
    Text1.Text = "No devices found"
  End If
End Sub

Private Sub Form_Load()
    'Enabled all ExceleTel TeleTools controls before using them
    etLine1.Enabled = True
    etPhone1.Enabled = True
    etPlay1.Enabled = True
    etRecord1.Enabled = True

    FillText
End Sub

Private Sub Form_Resize()
    If Form1.Width < 4800 Then
        Text1.Width = 4800 - (Text1.Left * 3)
    Else
        Text1.Width = Form1.Width - (Text1.Left * 3)
    End If
    If Form1.Height < 4890 Then
        Text1.Height = 4890 - Text1.Top - (Text1.Left * 4)
    Else
        Text1.Height = Form1.Height - Text1.Top - (Text1.Left * 4)
    End If
End Sub

Private Sub OptionData_Click()
    FillText
End Sub

Private Sub OptionFax_Click()
    FillText
End Sub

Private Sub OptionVoice_Click()
    FillText
End Sub